# Copyright 2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

themes_V=20160512

DESCRIPTION="Scaleable remake of LBreakout2 : Breakout clone written with the SDL2 library"
HOMEPAGE="http://lgames.sourceforge.net/LBreakoutHD/"
SRC_URI="mirror://sourceforge/lgames/${P}.tar.gz
	themes? ( mirror://sourceforge/lgames/add-ons/lbreakout2/lbreakout2-themes-${themes_V}.tar.gz )"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nls themes"

DEPEND="
	media-libs/libsdl2[joystick,sound,video]
	media-libs/sdl2-mixer[wav]
	media-libs/sdl2-image[jpeg,png]
	media-libs/sdl2-ttf[X]
	nls? ( sys-devel/gettext )
"
RDEPEND="${DEPEND}"
BDEPEND=""

src_unpack() {
	unpack ${P}.tar.gz

	if use themes ; then
		mkdir "${WORKDIR}/themes"
		cd "${WORKDIR}/themes"
		unpack lbreakout2-themes-${themes_V}.tar.gz

		for f in *.zip; do
			unzip -q "$f" && rm -f "$f" || die
		done
	fi
}

src_configure() {
	econf \
		--localedir=/usr/share/locale \
		$(use_enable nls)
}

src_install() {
	default

	if use themes ; then
		insinto /usr/share/lbreakouthd/themes
		doins -r "${WORKDIR}/themes/"*
	fi
}